***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 17, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt RB501V-40-AU A K
.param
+ vc0 = 7.652e-7	vc1 = 7.557e-8		vc2 = 2.011e-7		vc3 = 8.504e-2
+ tc1 = 6.228e-2	tc2 = 4.101e-2		tc3 = 4.874e-2		tc4 = 3.425e-2
d1 A K sbd
g1 K A value = {(vc0+vc1*v(K,A))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*exp(vc3*v(K,A)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model sbd d
***** flag parameter ***
+level = 1                     
***** dc model parameter *****
+ is = 5.476e-8		   n = 0.872		  rs = 7.519e-1
+ibv = 0.5e-3		 nbv = 1		  bv = 49.5
***** capacitance parameter *****
+cjo = 1.875e-11	   m = 4.875e-1		  vj = 5.935e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 0.548		 xti = 3
+trs1 = 5.716e-3	trs2 = 1.354e-5
.ends RB501V-40-AU
*$
